fork within loop with join ALL

Question

Hello,

I'd like to fork threads in a loop. So I use the classical approach:

for(int index=0;index<14;index++)begin
    automatic int idx=index;
    fork
        begin
            `ovm_do_on(sequence_inst,p_sequencer.my_sqr[idx]);
        end
    join_none;
end

And it works fine, except that I'd like to use "join" (all) instead of "join_none" since I have to wait for all the sequences to be completed before continuing the test case.
When I use "join", it looks like the sequences are not forked, but launched one after the other...

Any idea why it behaves like this?
I've fixed this by unfolding the loop into a big fork and it works fine, but I'm really curious why the use of "join" in this loop breaks the parallelization.

Thanks a lot &
BR

Answer 1

dave_59

Forum Moderator

10663 posts

May 31, 2012 at 10:10 am

Because fork/join is a blocking statement, only the statements inside the fork/join are executed in parallel.

What you need to do add a wait fork statement after the for loop. This block the current thread until all child threads have completed. You have to be careful if there are any other earlier fork_join_none statements that you do not want to wait for them to finish. If there are, the you need to create an isolating thread.

fork 
  begin : isolating_thread
    for(int index=0;index<14;index++)begin : for_loop
 
      fork
      automatic int idx=index;
        begin
            `ovm_do_on(sequence_inst,p_sequencer.my_sqr[idx]);
        end
      join_none;
    end : for_loop
  wait fork;
  end : isolating_thread
join

— Dave Rich, Verification Architect, Siemens EDA

Answer 2

Andreas38

Forum Access

19 posts

June 01, 2012 at 1:49 am

In reply to dave_59:

Hi Dave,

Thanks a lot for the explanation!
That works indeed perfectly.

Answer 3

VE

Full Access

112 posts

June 15, 2012 at 11:58 am

Dave :
I would like to know the purpose of using "wait fork" here ?
do you think fork/join actually already take care of wait fork? or it has to do something about child seqs of sequence_inst in Andreas38's example?
thanks in adv

Answer 4

dave_59

Forum Moderator

10663 posts

June 15, 2012 at 1:08 pm

In reply to aming:

The wait fork suspends the parent sequence (or test) until all the child sequences (processes) have completed. There reason you can't just use fork/join is because of the outer for_loop used to spawn each sequence (process) with a fork statement. If you used a fork/join, then each iteration of the loop would be blocked until the sequence completed, and the fork/join is not really doing anything different than a begin/end.

— Dave Rich, Verification Architect, Siemens EDA

Answer 5

VE

Full Access

112 posts

June 15, 2012 at 4:32 pm

Thanks Dave. I am afraid i still dont fully understand the usage of wait fork here. :(

I copied your code below, I understand that using fork/join_none inside of for-loop, and using fork/join(first line and last line of your code) to wait all threads created by for-loop to be completed, but i dont understand why there is still a wait fork statement befor join, does the fork/join ( first line and last line of your code ) already wait for all threads to be completed?

thank you

fork 
  begin : isolating_thread
    for(int index=0;index<14;index++)begin : for_loop
      fork
      automatic int idx=index;
        begin
            `ovm_do_on(sequence_inst,p_sequencer.my_sqr[idx]);
        end
      join_none;
    end : for_loop
  wait fork;
  end : isolating_thread
join

Answer 6

dave_59

Forum Moderator

10663 posts

June 16, 2012 at 12:32 am

In reply to aming:

A fork/join blocks until all direct child threads to complete. A fork/join block does not wait for its grandchildren threads to complete unless a child thread is blocked waiting for a grandchild thread.

In the example above there is only one child thread of the outer fork/join, the isolating_thread begin/end block. Without the wait fork statement, the isolating_thread would not block waiting for the grandchildren threads spawned by the fork/join_none inside the for loop.

Now the reason for the outer fork/join block is a bit trickier to explain, since we are only showing a fragment of code.

The wait fork statement blocks until all child threads of the current parent thread complete. We do not know if there were any other fork/join_none statements that came before this code snippet that we do not want to wait for, The isolating thread creates thread layer that guarantees that we only block waiting for the child threads of the isolating_thread.

— Dave Rich, Verification Architect, Siemens EDA

Answer 7

Nico75

Full Access

163 posts

March 12, 2015 at 3:27 pm

In these examples, the automatic variable is declared before the fork. In most other examples I have seen it inside the Fork. Are both equivalent? Before forking feels as if the variable isn't really belonging to the forked thread?

Answer 8

dave_59

Forum Moderator

10663 posts

March 12, 2015 at 5:34 pm

In reply to NiLu:

You are correct. There needs to be a separate idx variable for each invocation of the fork/join_none. I overlooked this since it was not the main point of the original question. I have edited the example.

— Dave Rich, Verification Architect, Siemens EDA

Answer 9

jhardy

Full Access

3 posts

December 14, 2015 at 7:13 pm

Is it possible to do something similar, but accomplish join_any behavior instead of join_all? All examples that I have seen on this topic always use the "wait fork" statement.

I am interested in starting multiple threads in parallel and joining them when just one completes. In particular, I want to wait for just one of any events to occur. I have tried a few variations of the following example, but without success.

Any help would be greatly appreciated. Thanks!

JH

fork
   begin
      foreach(my_cbs[i]) begin  // loop through an array of callbacks
         fork
            automatic int var_i = i;
            begin
               @(my_cbs[var_i].change_event);  // wait for an event triggered within the callback
            end
         join_none
      end
   end
join_any

Answer 10

Solution

dave_59

Forum Moderator

10663 posts

December 15, 2015 at 2:00 pm

In reply to jhardy:

begin
  event just_one_of any;
  foreach(my_cbs[i]) // loop through an array of callbacks
    fork
      int var_i = i;
         begin
               @(my_cbs[var_i].change_event);  // wait for an event triggered within the callback
               -> just_one_of_any;
         end
    join_none
  @just_one_of_any; 
end

— Dave Rich, Verification Architect, Siemens EDA

Answer 11

jhardy

Full Access

3 posts

December 16, 2015 at 2:05 pm

Thanks Dave! I appreciate the quick reply. Your suggestion solved my problem.

I assume that we still should declare the variable as automatic. Please correct correct me if I am wrong.

Answer 12

dave_59

Forum Moderator

10663 posts

December 16, 2015 at 2:35 pm

In reply to jhardy:
Yes. If this code is inside a class, then it is already automatic by default.

— Dave Rich, Verification Architect, Siemens EDA

Answer 13

dave_59

Forum Moderator

10663 posts

January 29, 2016 at 12:06 pm

In reply to theketi:
i < 8 has to fail in order to end the loop. So i will be 8 after exiting the loop.

— Dave Rich, Verification Architect, Siemens EDA

Answer 14

birenkumar

Full Access

24 posts

April 02, 2019 at 2:49 pm

In reply to dave_59:

Hello Dave,
I am trying to run below code :

        my_seq = new[2];
        fork 
            begin : isolating_thread
              for(int index=0;index<2;index++) begin : for_loop
                  automatic int idx=index;
                  automatic int local_qd=$urandom_range(1,4);
                  fork
                      `uvm_do_with(my_seq[idx],
                                    {
                                     qd           == local_qd;
                                    })
                  join_none;
              end : for_loop
            wait fork;
            end : isolating_thread
        join

I am getting below Error :

Quote:

=======================================================
Solver failed when solving following set of constraints

integer qd = 0;
integer local_qd = 4;

constraint WITH_CONSTRAINT // (from this) (constraint_mode = ON) (<File_path>:233)
{
(qd == local_qd);
}

=======================================================

Can you please help me with this ?? Thanks a lot in advance.
- Biren

Answer 15

dave_59

Forum Moderator

10663 posts

April 02, 2019 at 3:17 pm

In reply to birenkumar:

This likely has nothing to do with a fork statement. Maybe you did not declare qd as rand.

— Dave Rich, Verification Architect, Siemens EDA

Answer 16

zz8318

Full Access

172 posts

July 15, 2019 at 11:50 am

In reply to dave_59:

Hi Dave,

If I have two for-loop, how to handle it ? Is below code correct ?

fork 
  begin : isolating_thread
    for(int index=0;index<14;index++)begin : for_loop
      fork
      automatic int idx=index;
        for(int j=0;j<14;j++)begin 
         automatic int jdx=j;
        begin
            `ovm_do_on(sequence_inst,p_sequencer.my_sqr[idx][jdx]);
        end
      join_none;
    end : for_loop
  wait fork;
  end
  end : isolating_thread
join

Answer 17

Michael D Scott

Full Access

43 posts

April 17, 2020 at 6:05 am

In reply to zz8318:

Quote:

In reply to dave_59:

Hi Dave,

If I have two for-loop, how to handle it ? Is below code correct ?

fork 
  begin : isolating_thread
    for(int index=0;index<14;index++)begin : for_loop
      fork
      automatic int idx=index;
        for(int j=0;j<14;j++)begin 
         automatic int jdx=j;
        begin
            `ovm_do_on(sequence_inst,p_sequencer.my_sqr[idx][jdx]);
        end
      join_none;
    end : for_loop
  wait fork;
  end
  end : isolating_thread
join

That should work, not sure you need that second automatic variable assignment for j, but it shouldn't hurt.

I just ran into this problem yesterday... great thread.... I totally missed the part about the automatic variable for the fork.

Answer 18

SanjanaDhiran

Forum Access

6 posts

September 30, 2020 at 5:39 pm

In reply to dave_59:

With respect to the fork and join ALL inside for loop, I have a very basic question regarding the same.

for (i = 0; i<3;i++) begin
    automatic int j = i;
    fork 
       $display(j);
    join
end

Will the output for the above code will be :
0
1
2
???

Answer 19

dave_59

Forum Moderator

10663 posts

September 30, 2020 at 7:12 pm

In reply to SanjanaDhiran:

A fork/join with one statement behaves just like a begin/end block as far as your example is concerned.

— Dave Rich, Verification Architect, Siemens EDA

Answer 20

SanjanaDhiran

Forum Access

6 posts

October 01, 2020 at 9:36 am

In reply to dave_59:

Hie Dave,
Thank you for responding. However, I am still a little confused. Will my output be :
0
1
2
??

Answer 21

dave_59

Forum Moderator

10663 posts

October 01, 2020 at 9:54 am

In reply to SanjanaDhiran:

Are you able to try it your self? There is always www.edaplayground.com

— Dave Rich, Verification Architect, Siemens EDA

Answer 22

zz8318

Full Access

172 posts

May 24, 2022 at 6:44 am

In reply to dave_59:

Hi Dave,

I have a question here.

Is there any different between below two snippet of code ? (The different code is pointed out with comment)
I have thread_A() which is an isolated thread, and thread_B(i) which is parameterized with forloop variable, and another thread_C() in my code. I want all thread_B(i) are spawned in parallel and start the thread_C() when all of them finished. and above process is regarded as a whole thread, and run with thread_A in parallel. One of them finished then disable all others.

        fork
            thread_A();
            begin
                fork   // here is difference
                    for (int i = 0; i < 8; i++) begin
                        fork
                            automatic int j = i;
                            thread_B(j);
                        join_none
                    end
                    wait fork;
                join    // here is difference
                thread_C();
            end
        join_any
        disable fork;

        fork
            thread_A();
            begin
                for (int i = 0; i < 8; i++) begin
                    fork
                        automatic int j = i;
                        thread_B(j);
                    join_none
                end
                wait fork;
                thread_C();
            end
        join_any
        disable fork;

Answer 23

dave_59

Forum Moderator

10663 posts

May 24, 2022 at 1:03 pm

In reply to zz8318:

The wait fork waits for all child processes of the current thread to terminate. In your first example, any process created by thread_A are cousins, not children of the current thread. In your second example, any process created by thread_A are children of the current thread.

— Dave Rich, Verification Architect, Siemens EDA

Answer 24

zz8318

Full Access

172 posts

May 24, 2022 at 1:20 pm

In reply to dave_59:

Hi Dave,

How to determine which thread is current thread ?

and which one is correct to meet the requirement I mentioned in my last post ?

Answer 25

dave_59

Forum Moderator

10663 posts

May 24, 2022 at 1:39 pm

In reply to zz8318:

By current thread I mean from the perspective of the thread executing the wait fork statement. You should have enough information to make the correct decision.

— Dave Rich, Verification Architect, Siemens EDA

Answer 26

yourcheers

Full Access

108 posts

May 26, 2022 at 10:03 pm

module abc;
 
    task thread_A();
        #100;
    endtask
 
    task thread_B(int j);
        #2;
    endtask
 
    task thread_C();
        #30;
    endtask
 
    initial begin
 
        fork
            thread_A();
            begin
                fork   // here is difference
                    for (int i = 0; i < 8; i++) begin
                        fork
                            automatic int j = i;
                            thread_B(j);
                        join_none
                    end
                    wait fork;
                join    // here is difference
                thread_C();
            end
        join_any
        $display($time);
        disable fork;
    end 
 
    initial begin
        fork
            thread_A();
            begin
                for (int i = 0; i < 8; i++) begin
                    fork
                        automatic int j = i;
                        thread_B(j);
                    join_none
                end
                wait fork;
                thread_C();
            end
        join_any
        $display($time);
        disable fork;
    end
 
endmodule

Dave, can you help me with understanding the above example.
the first initial block is printing #30, expecting it to be 32 (thread_B + thread_C).
the second initial block is printing #32, expecting it to be 102 (thread_A + thread_B + thread_C) bcz of the "wait fork" inside the begin-end.

Answer 27

Rahulkumar

Full Access

173 posts

May 27, 2022 at 12:00 am

In reply to yourcheers:

These are valid results. Let me try to explain.

    // 1st initial block
    initial begin
        fork : fork_1
            thread_A();   // Thread 1 of fork_1
            begin  // Thread 2 of fork_1
                fork : fork_2  
                    for (int i = 0; i < 8; i++) begin //Thread 1 of fork_2
                        fork : fork_3
                            automatic int j = i;
                            thread_B(j);
                        join_none : fork_3
                    end
                    wait fork;  //Thread 2 of fork_2
                join : fork_2   
                thread_C();
            end
        join_any : fork_1
        $display($time);
        disable fork;
    end 
 
 //"wait fork;" is Thread 2 of fork_2. Thread 1 and Thread 2 are executing in parallel.  
 //None of the fork process were active during the execution of wait_fork. so it won't wait. so, Thread 2 finish at 0. 
 // Thread 1 will also finish in 0 time. Due to fork join_none (fork_3) 
 
    // fork_1
         //thread_A();  -> #100
         //begin _end  -> #30
    // join_any
    so, $display prints #30.
 
---------------------------------------------------------------------------------------
    //if you add begin....end fork 2 then you will see different 
    initial begin
        fork : fork_1
            thread_A();   // Thread 1 of fork_1
            begin  // Thread 2 of fork_1
                fork : fork_2  
                    begin /// ***Change***  //only Thread of fork_2
                        for (int i = 0; i < 8; i++) begin 
                            fork : fork_3
                               automatic int j = i;
                               thread_B(j);
                            join_none : fork_3
                        end
                    wait fork; 
                    end/// ***Change***
                join : fork_2   
                thread_C();
            end
        join_any : fork_1
        $display($time);
        disable fork;
    end

    //2nd initial block
    initial begin
        fork : fork_1
            thread_A();  //Thread 1 of fork_1
            begin  //Thread 2  of fork_1
                for (int i = 0; i < 8; i++) begin
                    fork : fork_3
                        automatic int j = i;
                        thread_B(j);
                    join_none : fork_3
                end
                wait fork;  // wait for fork_3 to finish 
                thread_C();
            end
        join_any : fork_1
        $display($time);
        disable fork;
    end
 
   // It have 2 Thread 
   // Thread 1 execution time is #100 which is thread_A() execution time
   // Thread 2 execution time is #32 which is thread_B()+thread_C() execution time
   //fork...join_any will wait for any one of the thread to finish. so, it display #32

______________________________________________________________________________________
https://www.linkedin.com/in/patel-rahulkumar/

Answer 28

yourcheers

Full Access

108 posts

May 27, 2022 at 11:00 am

In reply to dave_59:

Quote:

In reply to zz8318:
The wait fork waits for all child processes of the current thread to terminate. In your first example, any process created by thread_A are cousins, not children of the current thread. In your second example, any process created by thread_A are children of the current thread.

in the second example, as per Dave's explanation, thread_A is children of current thread, and shouldn't "wait-fork" wait for thread_A ?

Languages & Standards

Methodologies

Techniques & Tools

Universal Verification Methodology (UVM)

Featured Courses

Additional Courses

Formal-Based Techniques

Analog/Mixed Signal

UVM Forum

SystemVerilog Forum

Coverage Forum

Additional Forums

Implementation Patterns

Specification Patterns

Pattern Resources

UVM Cookbook

Coding Guidelines & Deployment

Coverage Cookbook

Featured & On-Demand

On-Demand Library

Recording Archive

Conferences & WRG

Siemens EDA Learning Center

Blog & News

Verification Horizons Publication

About Us

Training

Solution

Portfolio

Explore

Siemens

Contact