UVMC Command API Examples - Common SV Code

We implement each phase to simply print a message that the phase has started.  The UVMC Command API Example - Phase Control will show that SC can be synchronized to OVM phases and even prevent the task phases from ending.

virtual function void build();
  `ovm_info("OVMC_PHASING","BUILD Started",OVM_NONE);
endfunction

virtual function void connect();
  `ovm_info("OVMC_PHASING","CONNECT Started",OVM_NONE);
endfunction

virtual function void end_of_elaboration();
  `ovm_info("OVMC_PHASING","END_OF_ELABORATION Started",OVM_NONE);
endfunction

virtual function void start_of_simulation();
  `ovm_info("OVMC_PHASING","START_OF_SIMULATION Started",OVM_NONE);
endfunction

virtual function void extract();
  `ovm_info("OVMC_PHASING","EXTRACT Started",OVM_LOW);
endfunction

virtual function void check();
  `ovm_info("OVMC_PHASING","CHECK Started",OVM_LOW);
endfunction

virtual function void report();
  `ovm_info("OVMC_PHASING","REPORT Started",OVM_LOW);
endfunction

Creates a new producer object.  Here, we allocate the out port and ap analysis port.  If +PHASING_ON is not on the command line, we disable the OVMC_PHASING messages that are emitted by each phase callback (see above).

function new(string name, ovm_component parent=null);
   super.new(name,parent);
   out = new("out", this);
   ap = new("ap", this);
   //if (!$test$plusargs("PHASING_ON"))
    // set_report_id_action("OVMC_PHASING",OVM_NO_ACTION);
endfunction : new


// Function: check_config
//
// Enabled only during the <UVMC Command API Example - Configuration>,
// the ~check_config~ function gets the configuration parameters
// that the SC side should have set. It produces ERRORs in cases
// where a get was not successful.

// (begin inline source)
prod_cfg cfg = new();

function void check_config();

  int i;
  string str;
  ovm_object obj;

    if (!get_config_int("some_int",i))
      `ovm_error("NO_INT_CONFIG",{"No configuration for field 'some_int'",
         " found at context '",get_full_name(),"'"})
    else
      `ovm_info("INT_CONFIG",
         $sformatf("Config for field 'some_int' at context '%s' has value %0h",
         get_full_name(),i),OVM_NONE)


    if (!get_config_string("some_string",str))
      `ovm_error("NO_STRING_CONFIG",{"No configuration for field 'some_string'",
         " found at context '",get_full_name(),"'"})
    else
      `ovm_info("STRING_CONFIG",
         {"Config for field 'message' at context '", get_full_name(),
         "' has value '", str,"'"},OVM_NONE)

    if (!get_config_object("config",obj,0))
      `ovm_error("NO_OBJECT_CONFIG",{"No configuration for field 'config'",
         " found at context '",get_full_name(),"'"})
    else begin
       prod_cfg c;
       if (!$cast(c,obj))
         `ovm_error("BAD_CONFIG_TYPE",
            {"Object set for configuration field 'config' at context '",
            get_full_name(),"' is not a prod_cfg type"})
       else begin
         cfg = c;
         `ovm_info("OBJECT_CONFIG",
            {"Config for field 'config' at context '",get_full_name(),
            "' has value '", cfg.convert2string(),"'"},OVM_NONE)
       end
    end

endfunction

Produces the configured number of transactions, sending each to its out and ap analysis ports.  A prod_cfg configuration object governs how many transactions are produced and constrains the address range and data array length during randomization.  Upon return from sending the last transaction, the producer drops its objection to ending the run phase, thus allowing simulation to proceed to the next phase.

   virtual task run();

     bit enable_config_check = $test$plusargs("CONFIG_ON");
     bit enable_stimulus = $test$plusargs("TRANS_ON");

     if (enable_config_check)
       check_config();

     if (enable_stimulus) begin

       `ovm_info("OVMC_PHASING","RUN Started",OVM_LOW);

       if (cfg != null) begin

         ovm_test_done.raise_objection(this);

         for (int i = 1; i <= cfg.max_trans; i++) begin

           packet pkt = packet::type_id::create("pkt",this);

           pkt.cmd = i;

           if (!pkt.randomize() with {
              addr inside { [cfg.min_addr:cfg.max_addr] };
              data.size() inside { [cfg.min_data_len:cfg.max_data_len] }; })
             `ovm_error("RAND_FAILED",  "Randomization of tlm_gp failed")

           $display();
           `ovm_info("PRODUCER/SEND_PKT",
              $sformatf("SV producer sending packet #%0d\n  %s",i,
                        pkt.sprint(ovm_default_line_printer)),OVM_MEDIUM)

           ap.write(pkt);
           out.put(pkt);
         end

         ovm_test_done.drop_objection(this);

         `ovm_info("PRODUCER/DONE","Finished with stimulus",OVM_LOW)

       end

     end // enable_stimulues

     else begin
       global_stop_request();
     end

   endtask

endclass